Inhalt

Dieses Script fügt den aktuellen Bericht an die aktiven Projekte an. Das dient dazu, dass in der Rechnung das Eintrag - Alle Berichte drucken verwendet werden kann und nicht alle Berichte von Hand eingefügt werden müssen. Siehe dazu auch den Artikel Berichte fuer Rechnung.

Wenn Sie einen Bericht aus der Berichtliste der Projekte entfernen möchten, wählen Sie stattdessen das Script Berichte entfernen.

Version

Alle Versionen

Ausführen

Auf dem Bericht, den Sie zuordnen möchten. Es muss sich um einen Rechnungsbericht handeln (Klassen: Rechnung), das wird im Script aber überprüft.

Script

AddBerichtToProjektberichte.txt

Scripttext

'---Bezeichnung: Bericht zu Projekten hinzufügen
'   Klassen: Bericht
'   ObjectScript: Yes
'   ContainerScript: No
'   EventType: Kein
'---Dieses Script ordnet den aktuellen Bericht allen aktiven
'   Projekten als Bericht zu (Rechnung > Eintrag - Alle Berichte drucken).
'   Es wird überprüft, ob der Bericht ein Rechnungsbericht ist,
'   ansonsten wird der Vorgang abgebrochen.
'---17.02.2004, Vertec AG: erstellt.
'---30.05.2008, sc: Vertec und Argobject eingefügt

option explicit

dim projekt
dim bericht
dim projlist
dim berichtlist
dim i

set bericht = Vertec.argobject
if bericht.eval("oclisKindOf(Bericht)") then
  'Handelt es sich um einen Rechnungsreport?
  if bericht.eval("klassen->sqllike('%Rechnung%')") then
    'Alles klar, der Bericht kann verwendet werden
    set projlist= Vertec.eval("projekt->select(aktiv)")
    for i = 0 to projlist.count-1
      set projekt = projlist.Objects(i)
      set berichtlist=projekt.eval("berichte")
      berichtlist.add(bericht)
    next
    msgbox "Der Bericht wurde zugeordnet."
  else
    'Der Bericht ist kein Rechnungsbericht: Abbruch.
    msgbox "Der Bericht ist kein Rechnungsbericht. Der Vorgang wird abgebrochen.", 16, "Vertec"
  end if
else
  'Das aktuelle Objekt ist kein Bericht: Abbruch.
  msgbox "Das aktuelle Objekt ist kein Bericht. Der Vorgang wird abgebrochen.", 16, "Vertec"
end if